**Summary**

This document provides a script for automating the procedure of attaching and detaching USB mass storage devices from a given VM on XenServer.

This method is particularly useful in environments where USB storage such as removable hard disks is used for storing backups that are rotated on a regular basis.

**Requirements**

The following is required:

XenServer Host.

XenCenter installed on the host running the backup software.

USB Mass-storage device recognized by XenServer.

The usbmount.bat batch script.

**Background**

In some environments, USB mass storage devices are used for the purposes of backups. For this to be effective, the USB storage device is rotated and removed from the server after a backup.

Ordinarily, this process requires you to first confirm that the disk is not in use and then manually perform the detach operation. Similarly, when the disk is re-attached to the server, the storage must be again manually attached to the virtual machine.

Many different backup programs provide the ability to execute programs before and after a backup and using XenServer’s XE utility, it is entirely possible to automate this procedure.

**Procedure**

Install XenCenter

The batch program for handling the operation depends on the XE.EXE utility, a command-line interface client for executing commands on XenServer hosts. This utility is included as part of the XenCenter installation, hence XenCenter must be installed on the host on which you intend on running the utility.

If you choose to install XenCenter to a location other than C:\program files\citrix\XenCenter\ please take note of the exact installation path as you will need to modify the batch script accordingly.

Modify the usbmount.bat script

1. Using a text editor such as Notepad, edit the usbmount.bat script according to your requirements. The following attributes must be set:

2. Set the username, password and address (IP or hostname) of your XenServer host:

SET XE\_USERNAME=root  
SET XE\_PASSWORD=CHANGEME  
SET XE\_SERVER=xxx.xxx.xxx.xxx

3. Determine the universally unique identifier (UUID) of the Storage Repository that corresponds with the Removable Storage. You can determine this by running the following command from within your XenServer host console:

**xe sr-list name-label=Removable\ Storage**

4. Once you have the UUID of the Removable Storage, make the change to the script:

REM Removable Storage Repository UUID

SET REMOVABLE\_SR\_UUID=CHANGEME

5. Determine the UUID of the virtual machine (VM) you wish to attach the storage to. To do this, run:

**xe vm-list**

6. With the UUID of the VM, make the change to the script:

REM UUID of the VM you wish to attach the USB storage to

SET VM\_UUID=CHANGEME

7. Set the device order. It is important to ensure that there is no overlap and this is done by looking at the number of devices attached to the VM. For example, if only one storage device is currently being used (example: virtual hard disk), the next device name to use will be hdb.

REM Device name/order on the VM (example: hdb, hdc, hdd...)

SET DEVICE\_NAME=hdb

8. Run or Schedule the Batch Program

9. Once you have made the changes to the batch program, test it by running it from a Command Prompt window. Note that the utility requires a parameter, otherwise it exits.

10. To attach the USB storage device to the VM, run:

**usbmount.bat ATTACH**

11. To detach the USB storage device from the VM, run:

**usbmount.bat DETACH**

**Listing of USBMOUNT.BAT**

@ECHO OFF  
setlocal  
REM Attach a USB flash device to a specified VM on XenServer 4.x  
  
REM ------------- EDIT THE OPTIONS BELOW TO SUIT YOUR ENVIRONMENT -------------  
  
REM XenServer Credentials  
SET XE\_USERNAME=root  
SET XE\_PASSWORD=CHANGEME  
SET XE\_SERVER=xxx.xxx.xxx.xxx  
  
REM Removable Storage Repository UUID  
SET REMOVABLE\_SR\_UUID=CHANGEME  
  
REM UUID of the VM you wish to attach the USB storage to  
SET VM\_UUID=CHANGEME  
  
REM Device name/order on the VM (e.g. hdb, hdc, hdd...)  
set DEVICE\_NAME=hdb  
  
  
REM ---------------------------------------------------------------------------  
  
REM XenCenter Path  
SET XE\_CENTER\_PATH=C:\program files\citrix\XenCenter\  
  
REM XE Binary and Baseline Parameters  
SET XE\_EXEC="%XE\_CENTER\_PATH%\xe.exe" -s %XE\_SERVER% -u %XE\_USERNAME% -pw %XE\_PASSWORD%  
  
REM Temporary working file  
SET TEMP\_FILE=%TEMP%/xs-usbmount.tmp  
  
  
REM ------------ DO NOT EDIT BEYOND THIS LINE ----------------  
  
IF "%1"=="ATTACH" GOTO ATTACH\_STORAGE  
IF "%1"=="DETACH" GOTO DETACH\_STORAGE  
  
REM No parameters  
echo Usage USBMOUNT.BAT ^<ATTACH ^| DETACH^>  
GOTO END  
  
  
:DETACH\_STORAGE  
%XE\_EXEC% vdi-list sr-uuid=%REMOVABLE\_SR\_UUID% params=vbd-uuids --minimal > %TEMP\_FILE%  
SET /P VBD\_UUIDS= < %TEMP\_FILE%  
  
IF "%VBD\_UUIDS%"=="" GOTO NOT\_BOUND  
%XE\_EXEC% vbd-unplug uuid=%VBD\_UUIDS%  
%XE\_EXEC% vbd-destroy uuid=%VBD\_UUIDS%  
echo.Storage Detached  
  
GOTO END  
  
  
:ATTACH\_STORAGE  
  
REM See if the storage is already bound to a VBD  
%XE\_EXEC% vdi-list sr-uuid=%REMOVABLE\_SR\_UUID% params=vbd-uuids --minimal > %TEMP\_FILE%  
SET /P VBD\_UUIDS= < %TEMP\_FILE%  
  
IF NOT "%VBD\_UUIDS%"=="" GOTO ALREADY\_BOUND  
  
%XE\_EXEC% vdi-list sr-uuid=%REMOVABLE\_SR\_UUID% params=uuid --minimal > %TEMP\_FILE%  
SET /P VDI\_UUID= < %TEMP\_FILE%  
  
%XE\_EXEC% vbd-create vm-uuid=%VM\_UUID% device=%DEVICE\_NAME% vdi-uuid=%VDI\_UUID% --minimal > %TEMP\_FILE%  
SET /P VBD\_UUID= < %TEMP\_FILE%  
  
%XE\_EXEC% vbd-plug uuid=%VBD\_UUID%  
  
echo.VBD UUID attached as: %VBD\_UUID%  
GOTO END  
  
  
:ALREADY\_BOUND  
echo.Removable storage already attached to a VM - aborting.  
GOTO END  
  
:NOT\_BOUND  
echo.Storage device not bound to any VMs - aborting.  
GOTO END  
  
:END  
endlocal

**This document applies to:**